[VBS] Accessランタイムのセキュリティの警告を非表示にする方法

Const HKEY_CURRENT_USER = &H80000001
Const S_HKEY_CURRENT_USER = "HKEY_CURRENT_USER\"
Const TrustedLocations = "Software\Microsoft\Office\16.0\Access\Security\Trusted Locations\"

' 「信頼できる場所」に追加したいフォルダの設定
Const NewRegPath = "C:\Users\Public\Documents"  ' パス
Const NewRegDescription = "sampleDescription"   ' 説明文
Const NewRegAllowSubFolders = 1                 ' サブフォルダも追加する場合

Dim Locator, Service, Reg
Dim Shell
Dim SubKeySet, SubKey
Dim intLocation, intLocationMax
Dim strLocationNew
Dim strPathTmp

Set Locator = CreateObject("WbemScripting.SWbemLocator")
Set Service = Locator.ConnectServer(vbNullString, "root\default")
Set Reg = Service.Get("StdRegProv")
Set Shell = createobject("WScript.Shell")

' サブキーを全て取得する
Reg.EnumKey HKEY_CURRENT_USER, TrustedLocations, SubKeySet

' "LocationX" の"X"の最大値を取得する
intLocationMax = 0
for each SubKey in SubKeySet

    ' "LocationX" -> "X" に変換（数字のみにする）
    intLocation = CInt(replace(SubKey, "Location", ""))

    ' 最大値を更新
    if intLocationMax < intLocation then 
        intLocationMax = intLocation
    end if

    ' 登録済みかチェック（登録済みなら終了）
    strPathTmp = Shell.RegRead(S_HKEY_CURRENT_USER & TrustedLocations & _
                            "Location" & intLocation & "\Path")
    if strPathTmp = NewRegPath then
        ' Pathが登録済みのため、終了
        WScript.Quit(0)
    end if

next

' 信頼できる場所を新たに追加する（LocationX+1）
strLocationNew = S_HKEY_CURRENT_USER & TrustedLocations & _
                 "Location" & (intLocationMax + 1) 

' 「信頼できる場所」に追加したいパス
Shell.RegWrite strLocationNew & "\Path", NewRegPath, "REG_SZ"
' 説明文（わかりやすいように）
Shell.RegWrite strLocationNew & "\Description", NewRegDescription, "REG_SZ"
' サブフォルダも「信頼できる場所」に追加したい場合、以下も設定する（任意）
Shell.RegWrite strLocationNew & "\AllowSubFolders" , NewRegAllowSubFolders, "REG_DWORD"